但行好事
莫论前程❤

PL/SQL编程详解之二:PL/SQL块结构和组成元素

本篇主要内容如下:

  • PL/SQL块
  • PL/SQL结构
  • 标识符
  • PL/SQL 变量类型
    • 变量类型
    • 复合类型
    • 记录类型
    • 数组类型
    • 使用%TYPE
    • 使用%ROWTYPE
    • LOB类型
    • BIND 变量
    • PL/SQL 表(TABLE)
  • 运算符和表达式(数据定义)
    • 关系运算符
    • 一般运算符
    • 逻辑运算符
  • 变量赋值
    • 字符及数字运算特点
    • BOOLEAN 赋值
    • 数据库赋值
    • 可转换的类型赋值
  • 变量作用范围及可见性
  • 注释
  • 简单例子
    • 简单数据插入例子
    • 简单数据删除例子

PL/SQL块

  PL/SQL程序由三个块组成,即声明部分、执行部分、异常处理部分。

  PL/SQL块的结构如下:

DECLARE 
   --声明部分: 在此声明PL/SQL用到的变量,类型及游标,以及局部的存储过程和函数
 BEGIN
   -- 执行部分:  过程及SQL 语句  , 即程序的主要部分
 EXCEPTION
   -- 执行异常部分: 错误处理
 END;

其中:执行部分不能省略。

  PL/SQL块可以分为三类:

  • 无名块或匿名块(anonymous):动态构造,只能执行一次,可调用其它程序,但不能被其它程序调用。
  • 命名块(named):是带有名称的匿名块,这个名称就是标签。
  • 子程序(subprogram):存储在数据库中的存储过程、函数等。当在数据库上建立好后可以在其它程序中调用它们。
  • 触发器(Trigger):当数据库发生操作时,会触发一些事件,从而自动执行相应的程序。
  • 程序包(package):存储在数据库中的一组子程序、变量定义。在包中的子程序可以被其它程序包或子程序调用。但如果声明的是局部子程序,则只能在定义该局部子程序的块中调用该局部子程序。

PL/SQL结构

  • PL/SQL块中可以包含子块;
  • 子块可以位于 PL/SQL中的任何部分;
  • 子块也即PL/SQL中的一条命令;

标识符

  PL/SQL程序设计中的标识符定义与SQL 的标识符定义的要求相同。要求和限制有:

  • 标识符名不能超过30字符;

  • 第一个字符必须为字母;

  • 不分大小写;
  • 不能用’-‘(减号);
  • 不能是SQL保留字。

提示: 一般不要把变量名声明与表中字段名完全一样,如果这样可能得到不正确的结果.

 例如:下面的例子将会删除所有的纪录,而不是’EricHu’的记录;

DECLARE
   ename varchar2(20) :='EricHu';
BEGIN
  DELETE FROM scott.emp WHERE ename=ename;
END;

变量命名在PL/SQL中有特别的讲究,建议在系统的设计阶段就要求所有编程人员共同遵守一定的要求,使得整个系统的文档在规范上达到要求。下面是建议的命名方法:

标识符命名规则例子
程序变量V_nameV_name
程序常量C_NameC_company_name
游标变量Cursor_NameCursor_Emp
异常标识E_nameE_too_many
表类型Name_table_typeEmp_record_type
Name_tableEmp
记录类型Name_recordEmp_record
SQL*Plus 替代变量P_nameP_sal
绑定变量G_nameG_year_sal

PL/SQL 变量类型

  在前面的介绍中,有系统的数据类型,也可以自定义数据类型。下表给出ORACLE类型和PL/SQL中的变量类型的合法使用列表:

变量类型

  在ORACLE8i中可以使用的变量类型有:

类型子类说 明范 围ORACLE限制
CHARCharacterStringRowidNchar定长字符串 民族语言字符集0à32767可选,确省=12000
VARCHAR2Varchar, StringNVARCHAR2可变字符串民族语言字符集0à3276740004000
BINARY_INTEGER带符号整数,为整数计算优化性能
NUMBER(p,s)Dec Double precisionIntegerIntNumericRealSmall int小数, NUMBER 的子类型高精度实数整数, NUMBER 的子类型整数, NUMBER 的子类型与NUMBER等价与NUMBER等价整数, 比 integer 小
LONG变长字符串0->214748364732,767字节
DATE日期型公元前4712年1月1日至公元后4712年12月31日
BOOLEAN布尔型TRUE, FALSE,NULL不使用
ROWID存放数据库行号

1. 插入一条记录并显示;

DECLARE
   Row_id ROWID;
   info    VARCHAR2(40);
BEGIN
  INSERT INTO scott.dept VALUES (90, '财务室', '海口')
  RETURNING rowid, dname||':'||to_char(deptno)||':'||loc
  INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

其中:

RETURNING子句用于检索INSERT语句中所影响的数据行数,当INSERT语句使用VALUES 子句插入数据时,RETURNING 字句还可将列表达式、ROWID和REF值返回到输出变量中。在使用RETURNING 子句是应注意以下几点限制:

1.不能与DML语句和远程对象一起使用;

2.不能检索LONG 类型信息;

3.当通过视图向基表中插入数据时,只能与单基表视图一起使用。

2. 修改一条记录并显示

DECLARE
   Row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  UPDATE dept SET deptno=100 WHERE DNAME='财务室'
  RETURNING rowid, dname||':'||to_char(deptno)||':'||loc
  INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

其中:

RETURNING子句用于检索被修改行的信息。当UPDATE语句修改单行数据时,RETURNING 子句可以检索被修改行的ROWID和REF值,以及行中被修改列的列表达式,并可将他们存储到PL/SQL变量或复合变量中;当UPDATE语句修改多行数据时,RETURNING 子句可以将被修改行的ROWID和REF值,以及列表达式值返回到复合变量数组中。在UPDATE中使用RETURNING 子句的限制与INSERT语句中对RETURNING子句的限制相同。

3. 删除一条记录并显示

DECLARE
   Row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  DELETE dept WHERE DNAME='办公室'
  RETURNING rowid, dname||':'||to_char(deptno)||':'||loc
  INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

其中:

RETURNING子句用于检索被删除行的信息:当DELETE语句删除单行数据时,RETURNING 子句可以检索被删除行的ROWID和REF值,以及被删除列的列表达式,并可将他们存储到PL/SQL变量或复合变量中;当DELETE语句删除多行数据时,RETURNING 子句可以将被删除行的ROWID和REF值,以及列表达式值返回到复合变量数组中。在DELETE中使用RETURNING 子句的限制与INSERT语句中对RETURNING子句的限制相同。

复合类型

​ ORACLE 在 PL/SQL 中除了提供象前面介绍的各种类型外,还提供一种称为复合类型的类型—记录和表.

记录类型

记录类型类似于C语言中的结构数据类型,它把逻辑相关的、分离的、基本数据类型的变量组成一个整体存储起来,它必须包括至少一个标量型或RECORD数据类型的成员,称作PL/SQL RECORD 的域(FIELD),其作用是存放互不相同但逻辑相关的信息。在使用记录数据类型变量时,需要先在声明部分先定义记录的组成、记录的变量,然后在执行部分引用该记录变量本身或其中的成员。

定义记录类型语法如下 :

TYPE record_name IS RECORD(
   v1 data_type1  [NOT NULL]  [:= default_value ],
   v2 data_type2  [NOT NULL]  [:= default_value ],
   ......
   vn data_typen  [NOT NULL]  [:= default_value ] );

4 

DECLARE 
   TYPE test_rec IS RECORD(
         Name VARCHAR2(30) NOT NULL := '胡勇',
         Info VARCHAR2(100));
   rec_book test_rec;
BEGIN
   rec_book.Name :='胡勇';
   rec_book.Info :='谈PL/SQL编程;';
   DBMS_OUTPUT.PUT_LINE(rec_book.Name||'  ' ||rec_book.Info);
END;

可以用 SELECT语句对记录变量进行赋值,只要保证记录字段与查询结果列表中的字段相配即可。

5

DECLARE
--定义与hr.employees表中的这几个列相同的记录数据类型
   TYPE RECORD_TYPE_EMPLOYEES IS RECORD(
        f_name   hr.employees.first_name%TYPE,
        h_date   hr.employees.hire_date%TYPE,
        j_id     hr.employees.job_id%TYPE);
--声明一个该记录数据类型的记录变量
   v_emp_record RECORD_TYPE_EMPLOYEES;

BEGIN
   SELECT first_name, hire_date, job_id INTO v_emp_record
   FROM employees
   WHERE employee_id = &emp_id;

   DBMS_OUTPUT.PUT_LINE('雇员名称:'||v_emp_record.f_name
             ||'  雇佣日期:'||v_emp_record.h_date
             ||'  岗位:'||v_emp_record.j_id);
END;

一个记录类型的变量只能保存从数据库中查询出的一行记录,若查询出了多行记录,就会出现错误。

数组类型

数据是具有相同数据类型的一组成员的集合。每个成员都有一个唯一的下标,它取决于成员在数组中的位置。在PL/SQL中,数组数据类型是VARRAY。

定义VARRY 数据类型语法如下:

TYPE varray_name IS VARRAY(size) OF element_type [NOT NULL];

varray_name是VARRAY数据类型的名称,size是下整数,表示可容纳的成员的最大数量,每个成员的数据类型是element_type。默认成员可以取空值,否则需要使用NOT NULL加以限制。对于VARRAY数据类型来说,必须经过三个步骤,分别是:定义、声明、初始化。

6

DECLARE
--定义一个最多保存5个VARCHAR(25)数据类型成员的VARRAY数据类型
   TYPE reg_varray_type IS VARRAY(5) OF VARCHAR(25);
--声明一个该VARRAY数据类型的变量
   v_reg_varray REG_VARRAY_TYPE;

BEGIN
--用构造函数语法赋予初值
   v_reg_varray := reg_varray_type
         ('中国', '美国', '英国', '日本', '法国');

   DBMS_OUTPUT.PUT_LINE('地区名称:'||v_reg_varray(1)||'、'
                                    ||v_reg_varray(2)||'、'
                                    ||v_reg_varray(3)||'、'
                                    ||v_reg_varray(4));
   DBMS_OUTPUT.PUT_LINE('赋予初值NULL的第5个成员的值:'||v_reg_varray(5));
--用构造函数语法赋予初值后就可以这样对成员赋值
   v_reg_varray(5) := '法国';
   DBMS_OUTPUT.PUT_LINE('第5个成员的值:'||v_reg_varray(5));
END;

使用%TYPE

定义一个变量,其数据类型与已经定义的某个数据变量(尤其是表的某一列)的数据类型相一致,这时可以使用%TYPE。

使用%TYPE特性的优点在于:

  • 所引用的数据库列的数据类型可以不必知道;
  • 所引用的数据库列的数据类型可以实时改变,容易保持一致,也不用修改PL/SQL程序。

7

DECLARE
   -- 用%TYPE 类型定义与表相配的字段
   TYPE T_Record IS RECORD(
        T_no emp.empno%TYPE,
        T_name emp.ename%TYPE,
        T_sal emp.sal%TYPE );
   -- 声明接收数据的变量
   v_emp T_Record;
BEGIN
   SELECT empno, ename, sal INTO v_emp FROM emp WHERE empno=7788;
   DBMS_OUTPUT.PUT_LINE
    (TO_CHAR(v_emp.t_no)||' '||v_emp.t_name||'  ' || TO_CHAR(v_emp.t_sal));
END;

8

DECLARE
   v_empno emp.empno%TYPE :=&no;
   Type t_record is record (
        v_name   emp.ename%TYPE,
        v_sal    emp.sal%TYPE,
        v_date   emp.hiredate%TYPE);
   Rec t_record;
BEGIN
   SELECT ename, sal, hiredate INTO Rec FROM emp WHERE empno=v_empno;
   DBMS_OUTPUT.PUT_LINE(Rec.v_name||'---'||Rec.v_sal||'--'||Rec.v_date);
END;

使用%ROWTYPE

PL/SQL 提供%ROWTYPE操作符, 返回一个记录类型, 其数据类型和数据库表的数据结构相一致。

使用%ROWTYPE特性的优点在于:

  • 所引用的数据库中列的个数和数据类型可以不必知道;

  • 所引用的数据库中列的个数和数据类型可以实时改变,容易保持一致,也不用修改PL/SQL程序。

9

DECLARE
    v_empno emp.empno%TYPE :=&no;
    rec emp%ROWTYPE;
BEGIN
    SELECT * INTO rec FROM emp WHERE empno=v_empno;
    DBMS_OUTPUT.PUT_LINE('姓名:'||rec.ename||'工资:'||rec.sal||'工作时间:'||rec.hiredate); 
END;

LOB类型

​ ORACLE提供了LOB (Large OBject)类型,用于存储大的数据对象的类型。ORACLE目前主要支持BFILE, BLOB, CLOB 及 NCLOB 类型。

BFILE (Movie)

​ 存放大的二进制数据对象,这些数据文件不放在数据库里,而是放在操作系统的某个目录里,数据库的表里只存放文件的目录。

BLOB(Photo)

​ 存储大的二进制数据类型。变量存储大的二进制对象的位置。大二进制对象的大小<=4GB。

CLOB(Book)

​ 存储大的字符数据类型。每个变量存储大字符对象的位置,该位置指到大字符数据块。大字符对象的大小<=4GB。

NCLOB

​ 存储大的NCHAR字符数据类型。每个变量存储大字符对象的位置,该位置指到大字符数据块。大字符对象的大小<=4GB。

BIND 变量

绑定变量是在主机环境中定义的变量。在PL/SQL 程序中可以使用绑定变量作为他们将要使用的其它变量。为了在PL/SQL 环境中声明绑定变量,使用命令VARIABLE。例如:

VARIABLE return_code NUMBER
VARIABLE return_msg VARCHAR2(20)

可以通过SQL*Plus命令中的PRINT 显示绑定变量的值。例如:

PRINT return_code
PRINT return_msg

10

VARIABLE result NUMBER;
BEGIN
  SELECT (sal*10)+nvl(comm, 0) INTO :result FROM emp 
  WHERE empno=7844;
END;
--然后再执行
PRINT result

PL/SQL 表(TABLE)

定义记录表(或索引表)数据类型。它与记录类型相似,但它是对记录类型的扩展。它可以处理多行记录,类似于高级中的二维数组,使得可以在PL/SQL中模仿数据库中的表。

定义记录表类型的语法如下:

TYPE table_name IS TABLE OF element_type [NOT NULL]
INDEX BY [BINARY_INTEGER | PLS_INTEGER | VARRAY2];

关键字INDEX BY表示创建一个主键索引,以便引用记录表变量中的特定行。

方法描述
EXISTS(n)如果集合的第n个成员存在,则返回true
COUNT返回已经分配了存储空间即赋值了的成员数量
FIRSTLASTFIRST:返回成员的最低下标值LAST: 返回成员的最高下标值
PRIOR(n)返回下标为n的成员的前一个成员的下标。如果没有则返回NULL
NEXT(N)返回下标为n的成员的后一个成员的下标。如果没有则返回NULL
TRIMTRIM:删除末尾一个成员TRIM(n) :删除末尾n个成员
DELETEDELETE:删除所有成员DELETE(n) :删除第n个成员DELETE(m, n) :删除从n到m的成员
EXTENDEXTEND:添加一个null成员EXTEND(n):添加n个null成员EXTEND(n,i):添加n个成员,其值与第i个成员相同
LIMIT返回在varray类型变量中出现的最高下标值

11

DECLARE
  TYPE dept_table_type IS TABLE OF 
       dept%ROWTYPE INDEX BY BINARY_INTEGER;
  my_dname_table dept_table_type;
  v_count number(2) :=4;
BEGIN
  FOR int IN 1 .. v_count LOOP
    SELECT * INTO my_dname_table(int) FROM dept WHERE deptno=int*10;
  END LOOP;
  FOR int IN my_dname_table.FIRST .. my_dname_table.LAST LOOP
  DBMS_OUTPUT.PUT_LINE('Department number: '||my_dname_table(int).deptno);
  DBMS_OUTPUT.PUT_LINE('Department name: '|| my_dname_table(int).dname);
  END LOOP;
END;

12 :按一维数组使用记录表

DECLARE
--定义记录表数据类型
   TYPE reg_table_type IS TABLE OF varchar2(25)
   INDEX BY BINARY_INTEGER;
--声明记录表数据类型的变量
   v_reg_table REG_TABLE_TYPE;

BEGIN
   v_reg_table(1) := 'Europe';
   v_reg_table(2) := 'Americas';
   v_reg_table(3) := 'Asia';
   v_reg_table(4) := 'Middle East and Africa';
   v_reg_table(5) := 'NULL';

   DBMS_OUTPUT.PUT_LINE('地区名称:'||v_reg_table (1)||'、'
                                    ||v_reg_table (2)||'、'
                                    ||v_reg_table (3)||'、'
                                    ||v_reg_table (4));
   DBMS_OUTPUT.PUT_LINE('第5个成员的值:'||v_reg_table(5));
END;

13 :按二维数组使用记录表

DECLARE
--定义记录表数据类型
   TYPE emp_table_type IS TABLE OF employees%ROWTYPE
   INDEX BY BINARY_INTEGER;
--声明记录表数据类型的变量
   v_emp_table EMP_TABLE_TYPE;
BEGIN
   SELECT first_name, hire_date, job_id INTO
   v_emp_table(1).first_name,v_emp_table(1).hire_date, v_emp_table(1).job_id
   FROM employees WHERE employee_id = 177;
   SELECT first_name, hire_date, job_id INTO
   v_emp_table(2).first_name,v_emp_table(2).hire_date, v_emp_table(2).job_id
   FROM employees WHERE employee_id = 178;

   DBMS_OUTPUT.PUT_LINE('177雇员名称:'||v_emp_table(1).first_name
             ||'  雇佣日期:'||v_emp_table(1).hire_date
             ||'  岗位:'||v_emp_table(1).job_id);
   DBMS_OUTPUT.PUT_LINE('178雇员名称:'||v_emp_table(2).first_name
             ||'  雇佣日期:'||v_emp_table(2).hire_date
             ||'  岗位:'||v_emp_table(2).job_id);
END;

运算符和表达式(数据定义)

关系运算符

运算符意义
=等于
<> , != , ~= , ^=不等于
<小于
>大于
<=小于或等于
>=大于或等于

一般运算符

运算符意义
+加号
减号
*乘号
/除号
:=赋值号
=>关系号
..范围运算符
||字符连接符

逻辑运算符

运算符意义
IS NULL是空值
BETWEEN AND介于两者之间
IN在一列值中间
AND逻辑与
OR逻辑或
NOT取返,如IS NOT NULL, NOT IN

变量赋值

在PL/SQL编程中,变量赋值是一个值得注意的地方,它的语法如下:

variable := expression ;

variable 是一个PL/SQL变量, expression 是一个PL/SQL 表达式.

字符及数字运算特点

空值加数字仍是空值:NULL + < 数字> = NULL

空值加(连接)字符,结果为字符:NULL || <字符串> = < 字符串>

BOOLEAN 赋值

布尔值只有TRUE, FALSE及 NULL 三个值。如:

DECLARE
  bDone BOOLEAN;
BEGIN
  bDone := FALSE;
  WHILE NOT bDone LOOP
  Null;
  END LOOP;
END;

数据库赋值

​ 数据库赋值是通过 SELECT语句来完成的,每次执行 SELECT语句就赋值一次,一般要求被赋值的变量与SELECT中的列名要一一对应。如:

14

DECLARE
  emp_id    emp.empno%TYPE :=7788;
  emp_name  emp.ename%TYPE;
  wages     emp.sal%TYPE;
BEGIN
  SELECT ename, NVL(sal,0) + NVL(comm,0) INTO emp_name, wages 
  FROM emp WHERE empno = emp_id;
  DBMS_OUTPUT.PUT_LINE(emp_name||'----'||to_char(wages));
END;

提示:不能将 SELECT 语句中的列赋值给布尔变量

可转换的类型赋值

CHAR 转换为 NUMBER

使用 TO_NUMBER 函数来完成字符到数字的转换,如:

v_total := TO_NUMBER('100.0') + sal;

NUMBER 转换为 CHAR

​ 使用 TO_CHAR函数可以实现数字到字符的转换,如:

v_comm := TO_CHAR('123.45') || '元' ;

字符转换为日期:

使用 TO_DATE函数可以实现 字符到日期的转换,如:

v_date := TO_DATE('2001.07.03','yyyy.mm.dd');

日期转换为字符

使用 TO_CHAR函数可以实现日期到字符的转换,如:

v_to_day := TO_CHAR(SYSDATE, 'yyyy.mm.dd hh24:mi:ss') ;

变量作用范围及可见性

在PL/SQL编程中,如果在变量的定义上没有做到统一的话,可能会隐藏一些危险的错误,这样的原因主要是变量的作用范围所致。变量的作用域是指变量的有效作用范围,与其它高级语言类似,PL/SQL的变量作用范围特点是:

  • 变量的作用范围是在你所引用的程序单元(块、子程序、包)内。即从声明变量开始到该块的结束。
  • 一个变量(标识)只能在你所引用的块内是可见的。
  • 当一个变量超出了作用范围,PL/SQL引擎就释放用来存放该变量的空间(因为它可能不用了)。
  • 在子块中重新定义该变量后,它的作用仅在该块内。

15

DECLARE
   Emess char(80);
BEGIN

   DECLARE
      V1 NUMBER(4);
   BEGIN
      SELECT empno INTO v1 FROM emp WHERE LOWER(job)='president';
      DBMS_OUTPUT.PUT_LINE(V1);
   EXCEPTION
      When TOO_MANY_ROWS THEN
         DBMS_OUTPUT.PUT_LINE ('More than one president');
   END;

   DECLARE 
      V1 NUMBER(4);
   BEGIN
      SELECT empno INTO v1 FROM emp WHERE LOWER(job)='manager';
   EXCEPTION
      When TOO_MANY_ROWS THEN
          DBMS_OUTPUT.PUT_LINE ('More than one manager');
   END;

EXCEPTION
   When others THEN
      Emess:=substr(SQLERRM,1,80);
      DBMS_OUTPUT.PUT_LINE(emess);
END;

注释

​ 在PL/SQL里,可以使用两种符号来写注释,即:

l       使用双 ‘-‘ ( 减号) 加注释

PL/SQL允许用 – 来写注释,它的作用范围是只能在一行有效。如:

    V_Sal  NUMBER(12,2); -- 人员的工资变量。

l         使用 /*   */  来加一行或多行注释,如:

/***************/

/* 文件名: department_salary.sql      */

/* 作 者: EricHu                     */

/* 时 间: 2011-5-9                  */

/***************/

提示:被解释后存放在数据库中的 PL/SQL 程序,一般系统自动将程序头部的注释去掉。只有在 PROCEDURE 之后的注释才被保留;另外程序中的空行也自动被去掉。

简单例子

简单数据插入例子

16

/***********************************************/
/* 文件名: test.sql                  */
/* 说 明:
       一个简单的插入测试,无实际应用。*/
/* 作 者: EricHu                     */
/* 时 间: 2011-5-9                  */
/***********************************************/
DECLARE
  v_ename   VARCHAR2(20) := 'Bill';
  v_sal       NUMBER(7,2) :=1234.56;
  v_deptno   NUMBER(2) := 10;
  v_empno   NUMBER(4) := 8888;
BEGIN
  INSERT INTO emp ( empno, ename, JOB, sal, deptno , hiredate )  
  VALUES (v_empno, v_ename, 'Manager', v_sal, v_deptno, 
            TO_DATE('1954.06.09','yyyy.mm.dd') );
  COMMIT;
END;

简单数据删除例子

17

/***********************************************/
/* 文件名: test_deletedata.sql      */
/* 说 明:
       简单的删除例子,不是实际应用。 */
/* 作 者: EricHu                     */
/* 时 间: 2011-5-9                  */
/***********************************************/
DECLARE
  v_ename   VARCHAR2(20) := 'Bill';
  v_sal       NUMBER(7,2) :=1234.56;
  v_deptno   NUMBER(2) := 10;
  v_empno   NUMBER(4) := 8888;
BEGIN
  INSERT INTO emp ( empno, ename, JOB, sal, deptno , hiredate )  
VALUES ( v_empno, v_ename, ‘Manager’, v_sal, v_deptno, 
TO_DATE(’1954.06.09’,’yyyy.mm.dd’) );
  COMMIT;
END;
 DECLARE
  v_empno   number(4) := 8888;
BEGIN
  DELETE FROM emp WHERE empno=v_empno;
  COMMIT;
END;
赞(2) 打赏
未经允许不得转载:刘鹏博客 » PL/SQL编程详解之二:PL/SQL块结构和组成元素
分享到: 更多 (0)

评论 抢沙发

评论前必须登录!

 

觉得文章有用就打赏一下文章作者

支付宝扫一扫打赏

微信扫一扫打赏